PO.RES.Vol.GRV.DepthArea


Description

Gross rock volume from a table of planimetered contour areas: a structure map's areas against depth, or an isopach map's areas against thickness. Each pair of neighbouring contours bounds a slice, and the slices are summed by the trapezoidal rule, the pyramidal (frustum) rule, or the usual mix of the two, which takes the pyramidal rule where the smaller area is at most half the larger. Returns the gross rock volume in acre-ft, the unit `PO.RES.Vol.STOIIP` and `PO.RES.Vol.GIIP` take.

Formula

=LAMBDA(Depth, Area, Mode, LET( i, SEQUENCE(ROWS(Depth)), shift, --(i=TRANSPOSE(i)+1), d_prev, MMULT(shift, Depth), a_prev, MMULT(shift, Area), dh, ABS(Depth-d_prev)*(i>1), trap, dh*(Area+a_prev)/2, pyr, dh*(Area+a_prev+SQRT(Area*a_prev))/3, lo, (Area+a_prev-ABS(Area-a_prev))/2, hi, (Area+a_prev+ABS(Area-a_prev))/2, IF(Mode=1, SUM(trap), IF(Mode=2, SUM(pyr), IF(Mode=3, SUM(IF(lo<=0.5*hi, pyr, trap)), NA())))))

Parameters

Parameter Unit Description
Depth ft Contour values, one column: depths from the crest down, or isopach thicknesses; at least two rows, in order
Area acres Area enclosed by each contour, same rows as Depth
Mode — 1 trapezoidal, 2 pyramidal, 3 pyramidal where the smaller area of a slice is at most half the larger and trapezoidal otherwise

Examples

Invocation Expected
=PO.RES.Vol.GRV.DepthArea({5000;5010;5020;5030;5040}, {0;100;250;420;600}, 1) 10700
=PO.RES.Vol.GRV.DepthArea({5000;5010;5020;5030;5040}, {0;100;250;420;600}, 2) 10413.82311
=PO.RES.Vol.GRV.DepthArea({5000;5010;5020;5030;5040}, {0;100;250;420;600}, 3) 10477.04628
=PO.RES.Vol.GRV.DepthArea({0;10;20;30}, {500;300;120;0}, 1) 6700
=PO.RES.Vol.GRV.DepthArea({0;10;20;30}, {500;300;120;0}, 2) 6390.116647
=PO.RES.Vol.GRV.DepthArea({0;10;20;30}, {500;300;120;0}, 3) 6432.455532

Need a custom LAMBDA? Suggest a New Lambda