PO.CO.Tubing.Buckling
Description
Lubinski's buckling effect: tubing compressed above its packer coils into a helix against the casing and shortens. Returns the length change and the buckled length above the packer, from the fictitious force at the packer and a critical helical load. Returns two cells: ΔL4 = −r² (Ff² − F²low) / (8 E I w) in., then the buckled length (Ff − Flow) / W ft, both 0 when Ff ≤ Fcr.
Formula
=LAMBDA(Ff_lbf, Fcr_lbf, TbgL_ft, TbgOD_in, TbgID_in, CsgID_in, W_lbft, TbgE_psi, LET(
mi, PI()/64*(TbgOD_in^4 - TbgID_in^4),
clr, (CsgID_in - TbgOD_in)/2,
fLow, MAX(Fcr_lbf, Ff_lbf - W_lbft*TbgL_ft),
bkl, Ff_lbf > Fcr_lbf,
HSTACK(IF(bkl, (fLow^2 - Ff_lbf^2)*clr^2/(8*TbgE_psi*mi*W_lbft/12), 0), IF(bkl, (Ff_lbf - fLow)/W_lbft, 0))))Parameters
| Parameter | Unit | Description |
|---|---|---|
Ff_lbf |
lbf | Fictitious force at the packer, Ap (ΔPi − ΔPo) plus any slack-off; compression positive |
Fcr_lbf |
lbf | Critical helical load, from PO.DE.TD.Buckling.Helical; 0 for Lubinski's original form |
TbgL_ft |
ft | Tubing length above the packer |
TbgOD_in |
in | Tubing outside diameter |
TbgID_in |
in | Tubing inside diameter |
CsgID_in |
in | Casing inside diameter; the radial clearance is r = (CsgID − OD) / 2 |
W_lbft |
lb/ft | Ws + Wi − Wo, the buoyed weight with the inside and outside fluids, from PO.DE.TD.Buoyancy |
TbgE_psi |
psi | Young's modulus, 30,000,000 for steel |
Examples
| Invocation | Expected |
|---|---|
=PO.CO.Tubing.Buckling(24887.304303, 0, 10000, 2.875, 2.441, 6.276, 5.646565, 30000000) |
[-9.845212, 4407.512321] |
=PO.CO.Tubing.Buckling(24887.304303, 5000, 10000, 2.875, 2.441, 6.276, 5.646565, 30000000) |
[-9.447829, 3522.018201] |
=PO.CO.Tubing.Buckling(24887.304303, 0, 2000, 2.875, 2.441, 6.276, 5.646565, 30000000) |
[-6.907731, 2000] |
=PO.CO.Tubing.Buckling(4000, 5000, 10000, 2.875, 2.441, 6.276, 5.646565, 30000000) |
[0, 0] |