PO.SF.Comp.Power


Description

Returns the head per stage, the gas power per stage or the total gas power to compress a gas rate from a suction to a discharge pressure in equal-ratio stages, with the gas cooled back to the suction temperature between stages. The mode is required: "Adiabatic" takes the isentropic head and the isentropic efficiency, the usual basis for reciprocating machines; "Polytropic" takes the polytropic head and the polytropic efficiency, the usual basis for centrifugal ones. The result is gas power, the power delivered to the gas: brake power adds the mechanical losses (bearings, seals, gear), which the caller adds.

Formula

=LAMBDA(mode, qg, ps, pd, t, sg, z, k, eff, stages, output, IF(OR(AND(mode<>"Adiabatic", mode<>"Polytropic"), qg<=0, ps<=0, pd<ps, t<=-459.67, sg<=0, z<=0, k<=1, eff<=0, eff>1, stages<1, stages<>INT(stages)), NA(), IF(OR(output="Head", output="Stage", output="Total"), z*1545.349*(t+459.67)/(28.9625*sg)/IF(mode="Polytropic", (k-1)/(k*eff), (k-1)/k)*(((pd/ps)^(1/stages))^IF(mode="Polytropic", (k-1)/(k*eff), (k-1)/k)-1)*IF(output="Head", 1, qg*1000000*14.696/(10.7316*519.67)*(28.9625*sg)/1440)/IF(output="Head", 1, eff*33000)*IF(output="Total", stages, 1), NA())))

Parameters

Parameter Unit Description
mode text "Adiabatic" (isentropic head and efficiency) or "Polytropic" (polytropic head and efficiency)
qg MMscf/d Gas rate at standard conditions (14.696 psia, 60 °F)
ps psia Suction pressure of the first stage
pd psia Final discharge pressure; at least `ps`
t °F Suction temperature of every stage (intercooled back to it)
sg air = 1 Gas specific gravity
z — Average compressibility factor of a stage, suction and discharge
k — Ratio of specific heats Cp/Cv, above 1 (`PO.SF.Comp.k`)
eff — Isentropic efficiency ("Adiabatic") or polytropic efficiency ("Polytropic"), above 0 and at most 1
stages — Number of stages, a whole number of 1 or more (`PO.SF.Comp.Stages`)
output text "Head" head per stage [ft·lbf/lbm], "Stage" gas power per stage [hp] or "Total" gas power of all stages [hp]

Examples

Invocation Expected
=PO.SF.Comp.Power("Adiabatic", 1, 100, 300, 80, 0.553923, 0.98513, 1.296663, 1, 1, "Total") 56.904454
=PO.SF.Comp.Power("Adiabatic", 1, 100, 300, 80, 0.553923, 0.98513, 1.296663, 1, 1, "Total") 56.853
=PO.SF.Comp.Power("Adiabatic", 1, 100, 300, 80, 0.553923, 0.98513, 1.296663, 0.8, 1, "Total") 71.067
=PO.SF.Comp.Power("Adiabatic", 10, 100, 1000, 80, 0.65, 0.95, 1.27, 0.8, 2, "Head") 54896.91007
=PO.SF.Comp.Power("Adiabatic", 10, 100, 1000, 80, 0.65, 0.95, 1.27, 0.8, 2, "Stage") 716.370849
=PO.SF.Comp.Power("Adiabatic", 10, 100, 1000, 80, 0.65, 0.95, 1.27, 0.8, 2, "Total") 1432.741699
=PO.SF.Comp.Power("Polytropic", 10, 100, 1000, 80, 0.65, 0.95, 1.27, 0.78, 2, "Head") 56916.17094
=PO.SF.Comp.Power("Polytropic", 10, 100, 1000, 80, 0.65, 0.95, 1.27, 0.78, 2, "Total") 1523.530173
=PO.SF.Comp.Power("Polytropic", 25, 300, 1200, 100, 0.7, 0.92, 1.25, 0.75, 1, "Total") 2466.925653
=IF(ISNA(PO.SF.Comp.Power("Isothermal", 25, 300, 1200, 100, 0.7, 0.92, 1.25, 0.75, 1, "Total")), 1, 0) 1
=IF(ISNA(PO.SF.Comp.Power("Adiabatic", 25, 300, 1200, 100, 0.7, 0.92, 1.25, 0.75, 1.5, "Total")), 1, 0) 1

Need a custom LAMBDA? Suggest a New Lambda