PO.RES.Waterflood.FractionalFlow
Description
Buckley-Leverett displacement of oil by water on Corey relative permeability curves. The function returns the water fractional flow fw at a water saturation, or one of the numbers Welge's tangent gives: the shock-front saturation, fw at the front, the average water saturation behind the front at breakthrough, and the pore volumes injected by then. Breakthrough recovery follows as (Sw̄ − Swi)/(1 − Swi).
Formula
=LAMBDA(Sw, Swi, Sor, kro_end, krw_end, no, nw, mu_o, mu_w, output, LET(
mob, 1-Swi-Sor,
grid_a, SEQUENCE(399)/400,
lw_a, krw_end*grid_a^nw/mu_w,
ratio_a, lw_a/(lw_a+kro_end*(1-grid_a)^no/mu_o)/grid_a,
idx_a, MATCH(MAX(ratio_a), ratio_a, 0),
grid_b, (idx_a-1+SEQUENCE(400)/200)/400,
lw_b, krw_end*grid_b^nw/mu_w,
ratio_b, lw_b/(lw_b+kro_end*(1-grid_b)^no/mu_o)/grid_b,
snf, INDEX(grid_b, MATCH(MAX(ratio_b), ratio_b, 0)),
lwf, krw_end*snf^nw/mu_w,
fwf, lwf/(lwf+kro_end*(1-snf)^no/mu_o),
pv_bt, IF(mob>0, mob*snf/fwf, 0),
sn, IF(mob>0, MIN(1, MAX(0, (Sw-Swi)/mob)), 0),
lw, krw_end*sn^nw/mu_w,
fw, lw/(lw+kro_end*(1-sn)^no/mu_o),
IF(mob<=0, NA(), IF(output="fw", fw, IF(output="Swf", Swi+mob*snf, IF(output="fwf", fwf, IF(output="Swbar", Swi+pv_bt, IF(output="PVbt", pv_bt, NA()))))))))Parameters
| Parameter | Unit | Description |
|---|---|---|
Sw |
fraction | Water saturation at which fw is returned (any value for the other outputs) |
Swi |
fraction | Irreducible (initial) water saturation |
Sor |
fraction | Residual oil saturation to water |
kro_end |
fraction | Oil relative permeability at Swi |
krw_end |
fraction | Water relative permeability at 1 − Sor |
no |
dimensionless | Corey oil exponent |
nw |
dimensionless | Corey water exponent |
mu_o |
cp | Oil viscosity |
mu_w |
cp | Water viscosity |
output |
text | "fw", "Swf" (shock-front Sw), "fwf" (fw at the front), "Swbar" (average Sw behind the front at breakthrough) or "PVbt" (pore volumes injected at breakthrough) |
Examples
| Invocation | Expected |
|---|---|
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.2, 0.8, 0.3, 2, 2, 5, 1, "Swf") |
0.554 |
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.2, 0.8, 0.3, 2, 2, 5, 1, "Swf") |
0.553861 |
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.2, 0.8, 0.3, 2, 2, 5, 1, "fw") |
0.652173913 |
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.2, 0.8, 0.3, 2, 2, 5, 1, "fwf") |
0.794884 |
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.2, 0.8, 0.3, 2, 2, 5, 1, "Swbar") |
0.645173 |
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.2, 0.8, 0.3, 2, 2, 5, 1, "PVbt") |
0.445173 |
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.25, 1, 0.35, 2.5, 2, 5, 0.5, "Swf") |
0.444291 |
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.2, 1, 1, 1, 1, 0.5, 1, "Swf") |
0.8 |
=PO.RES.Waterflood.FractionalFlow(0.5, 0.2, 0.2, 1, 1, 1, 1, 0.5, 1, "Swbar") |
0.8 |
=IF(ISERROR(PO.RES.Waterflood.FractionalFlow(0.5, 0.5, 0.5, 1, 0.3, 2, 2, 5, 1, "Swf")), 1, 0) |
1 |