PO.PTA.MDH.Fit
Description
The Miller-Dyes-Hutchinson straight-line fit of a drawdown: the least-squares line through the pressure drop against log10 of time over the radial-flow points you pass, and the permeability and skin it gives. Pass only the points inside the infinite-acting radial-flow window, for example with `FILTER`. It also fits a multi-rate drawdown: pass the superposition time `PO.PTA.Superposition.Time(…, "te")` as t, the pressure drop scaled to a reference rate, Δp·qref/qn, as dp, and qref as q.
Formula
=LAMBDA(t, dp, q, B, mu, h, phi, ct, rw, output, LET(
x, LOG10(t),
m, SLOPE(dp, x),
dp_1h, INTERCEPT(dp, x),
perm, 162.6*q*B*mu/(m*h),
skin, 1.151*(dp_1h/m-LOG10(perm/(phi*mu*ct*rw^2))+3.23),
IF(m<=0, NA(), IF(output="k", perm, IF(output="S", skin, IF(output="m", m, IF(output="dp1h", dp_1h, NA())))))))Parameters
| Parameter | Unit | Description |
|---|---|---|
t |
h | Elapsed times of the radial-flow points (or superposition times), all > 0 |
dp |
psi | Pressure drop pi − pwf at each time |
q |
bbl/d | Flow rate (the reference rate for a multi-rate fit) |
B |
bbl/STB | Formation volume factor |
mu |
cp | Viscosity |
h |
ft | Net pay thickness |
phi |
fraction | Porosity |
ct |
1/psi | Total compressibility |
rw |
ft | Wellbore radius |
output |
text | "k" permeability [mD], "S" skin [dimensionless], "m" slope [psi/cycle] or "dp1h" the line's Δp at 1 h [psi] |
Examples
| Invocation | Expected |
|---|---|
=PO.PTA.MDH.Fit({1;10;100}, {200;222;244}, 348, 1.14, 3.93, 130, 0.2, 0.00000874, 0.25, "k") |
88.64028705 |
=PO.PTA.MDH.Fit({1;10;100}, {200;222;244}, 348, 1.14, 3.93, 130, 0.2, 0.00000874, 0.25, "S") |
4.611011815 |
=PO.PTA.MDH.Fit({1;10;100}, {200;222;244}, 348, 1.14, 3.93, 130, 0.2, 0.00000874, 0.25, "m") |
22 |
=PO.PTA.MDH.Fit({1;10;100}, {200;222;244}, 348, 1.14, 3.93, 130, 0.2, 0.00000874, 0.25, "dp1h") |
200 |
=PO.PTA.MDH.Fit({10;100}, {560;620}, 250, 1.25, 1, 30, 0.2, 0.000015, 0.354, "k") |
28.22916667 |
=PO.PTA.MDH.Fit({10;100}, {560;620}, 250, 1.25, 1, 30, 0.2, 0.000015, 0.354, "S") |
4.244615275 |