PO.PTA.Superposition.Time


Description

The superposition time of a variable-rate drawdown, the abscissa that collapses every rate period onto one semilog straight line. Plot the pressure drop over the current rate, Δp/qn, against X (or against te on a log axis): in radial flow the points of every period fall on one line whose slope gives k and whose intercept gives the skin. With a single rate, te is the elapsed time itself. The rate history is laid out as `PO.PTA.Pw.VW`'s `prod_data`, so the same range drives the forward model and the interpretation.

Formula

=LAMBDA(t, prod_data, output, LET( ts, INDEX(prod_data, 0, 1), q, INDEX(prod_data, 0, 2), i, SEQUENCE(ROWS(ts)), active, --(ts<t), n, SUM(active), q_prev, MMULT(--(i=TRANSPOSE(i)+1), q), q_now, IF(n=0, 0, INDEX(q, MAX(active*i))), x, IF(q_now=0, 0, SUM(active*(q-q_prev)*LOG10(active*(t-ts)+(1-active)))/q_now), IF(q_now=0, NA(), IF(output="X", x, IF(output="te", 10^x, NA())))))

Parameters

Parameter Unit Description
t h Elapsed time since the first rate began, inside a flowing period
prod_data h, bbl/d One row per rate step: its start time in the first column, rising, and the rate from then on in the second
output text "te" for the superposition time [h], "X" for the Odeh-Jones coordinate log10(te) [dimensionless]

Examples

Invocation Expected
=PO.PTA.Superposition.Time(20, {0,100;10,50}, "te") 40
=PO.PTA.Superposition.Time(20, {0,100;10,50}, "X") 1.602059991
=PO.PTA.Superposition.Time(30, {0,250;24,500;48,125}, "te") 13.41640786
=PO.PTA.Superposition.Time(60, {0,250;24,500;48,125}, "te") 2700
=PO.PTA.Superposition.Time(5, {0,100;10,50}, "te") 5
=IF(ISNA(PO.PTA.Superposition.Time(30, {0,250;24,0}, "te")), 1, 0) 1

Need a custom LAMBDA? Suggest a New Lambda