Description
Where should the casing shoes go, and does each string carry its burst, collapse and tension loads with the design factors your policy asks for? You enter a shale sonic or resistivity log, its normal trends, two leak-off tests, the shoe depths and margins, and each string's diameter, grade and two sections. You read off pore pressure, fracture gradient and the mud program by depth, whether each seat holds, and each string's burst, collapse, tension and triaxial design factors. Field units; no add-in needed.
How to use it: The well and its log are synthetic. Paste the shale depths, transit times and resistivities into the Pore Pressure sheet, pick the log to read, set the normal trends over a normally pressured interval, and calibrate Poisson's ratio to the area's leak-off tests. Check that both seats pass and that the narrowest mud-weight window is workable. Take the minimum design factors from the company's casing policy, enter each string's grade, weights and walls on the Casing sheet, and read each string's design factors and what it misses there; the Summary gathers the verdicts.
Method: Pore pressure by Eaton: Pp = Sv − (Sv − Pn)(Δtn/Δt)³ from the sonic, or with (R/Rn)^1.2 from the resistivity, the normal trends exponential in depth. The overburden integrates Gardner's bulk density ρb = 0.23 V^0.25. Fracture gradient: Eaton's Pp + ν/(1 − ν)(Sv − Pp) and Matthews and Kelly's Pp + Ki(Sv − Pp). A leak-off test gives the ν that fits it, (LOT − Pp)/(Sv + LOT − 2Pp). Each hole's mud is the most the pore pressure plus the trip margin needs, rounded up to 0.1 ppg; a seat passes when the next hole's mud plus the kick margin is under the fracture gradient at the shoe. Each string is loaded by working-stress cases: burst for gas to surface from the next TD's pore pressure (to 0.1 ppg) and for lost returns at the shoe's fracture pressure, both against a water backup; collapse for full evacuation against the mud. Ratings are API TR 5C3's burst, collapse (lowered by the buoyed tension) and pipe-body yield; the triaxial check is von Mises at the top joint's inner wall.
Example: The drilling family's reference well. Normal pressure 8.94 ppg; the overburden reaches 18.31 ppg at TD. Pore pressure 10.19 ppg at the 10,000 ft intermediate shoe and 13.60 ppg at 13,000 ft TD; Eaton's fracture gradient 14.41 ppg at the 4,000 ft surface shoe, 15.42 ppg at the intermediate (Matthews-Kelly 15.36) and 16.74 ppg at TD. Muds 9.3, 10.5 and 13.9 ppg; both seats hold; the narrowest window is 1.79 ppg at 10,500 ft. Eaton's line misses the 14.5 and 15.3 ppg leak-off tests by −0.09 and +0.12 ppg. Surface casing, 13⅜-in. L-80 68 lb/ft over 72 lb/ft from 3,000 ft: a 10.2 ppg kick at 10,000 ft leaves 4,304 psi at the wellhead, burst design factor 1.17; collapse 1.38 at the shoe. Intermediate, 9⅝-in. P-110 47 over 53.5 lb/ft from 8,000 ft (the same string as the casing blueprint): burst 1.20 at the top under 7,894 psi, collapse 1.20 at the crossover, tension 3.68, triaxial 1.50. Production, 7-in. P-110 29 over 32 lb/ft from 10,000 ft: burst 1.42, collapse 1.15 at TD under 9,396 psi of 13.9 ppg mud, tension 3.06, triaxial 1.75. Every string meets the minimum design factors of 1.1 burst, 1.125 collapse, 1.6 tension and 1.25 triaxial. Run the 47 lb/ft to 9,500 ft and its collapse design factor falls to 1.02, below the minimum.
Validity
Eaton's method holds for shale under disequilibrium compaction; it under-reads unloading overpressure, where Bowers's unloading method is the alternative; the add-in has no function for it. Gardner's law overstates gas sands, salt and anhydrite. The fracture gradients are for a relaxed basin; with tectonic stress use a minimum horizontal stress from a stress model. Muds are static, with no ECD. The casing loads are uniaxial working-stress lines with constant gradients: the gas line is not capped at the shoe's fracture pressure (an upper bound), and the tension is the buoyed string hanging in one mud, without cement, temperature, ballooning, bending or running loads. The production string takes the same cases; its usual tubing-leak burst case on packer fluid is a named alternative. Ratings are the pipe body's; connections are separate. Named alternatives: the von Mises check at any depth for a full triaxial envelope, the partial-evacuation collapse case, and the pore-pressure blueprint's barite weight-up. Vertical well.
References
- Eaton, B.A. (1975). "The Equation for Geopressure Prediction from Well Logs." SPE-5544.
- Eaton, B.A. (1969). "Fracture Gradient Prediction and Its Application in Oilfield Operations." JPT (October).
- Matthews, W.R. and Kelly, J. (1967). "How to Predict Formation Pressure and Fracture Gradient." Oil and Gas Journal (20 February).
- American Petroleum Institute (2008). API TR 5C3 / ISO/TR 10400:2007 (burst, collapse, pipe-body yield, triaxial yield); API 5CT (casing dimensions and grades).
- Bourgoyne, A.T. et al. (1986). Applied Drilling Engineering. SPE Textbook Series Vol. 2, ch. 6 and 7.
Inputs
| Input | Unit | Default | Name |
|---|---|---|---|
| Log the pore pressure is read from (Sonic or Resistivity, from a list) | — | Sonic | PPW_Log |
| Normal (hydrostatic) pore-pressure gradient | psi/ft | 0.465 | PPW_Pn |
| Sonic normal trend at the surface, Δtn = Δt0·e^(−c·z) | µs/ft | 170 | PPW_Dt0 |
| Sonic normal trend's decay with depth, c | 1/ft | 6E-05 | PPW_DtC |
| Resistivity normal trend at the surface, Rn = R0·e^(b·z) | ohm·m | 0.6 | PPW_R0 |
| Resistivity normal trend's growth with depth, b | 1/ft | 8E-05 | PPW_RC |
| Bulk density above the first log depth | g/cm³ | 1.95 | PPW_RhoTop |
| Gardner coefficient (velocity in ft/s) | — | 0.23 | PPW_GA |
| Gardner exponent | — | 0.25 | PPW_GB |
| Poisson's ratio for Eaton, calibrated to leak-off tests | — | 0.4 | PPW_Nu |
| Matthews-Kelly Ki at zero equivalent depth | — | 0.4 | PPW_Ki0 |
| Matthews-Kelly Ki's rise per foot of equivalent depth | 1/ft | 3E-05 | PPW_KiSlope |
| Surface casing shoe (TVD) | ft | 4000 | PPW_Shoe1 |
| Intermediate casing shoe (TVD) | ft | 10000 | PPW_Shoe2 |
| Total depth of the production hole (TVD) | ft | 13000 | PPW_TD |
| Trip margin over the pore pressure | ppg | 0.3 | PPW_Trip |
| Kick margin under the fracture gradient | ppg | 0.5 | PPW_Kick |
| Depth of leak-off test 1 (TVD) | ft | 4000 | PPW_Lot1Z |
| Leak-off test 1, as an equivalent mud weight | ppg | 14.5 | PPW_Lot1 |
| Depth of leak-off test 2 (TVD) | ft | 10000 | PPW_Lot2Z |
| Leak-off test 2, as an equivalent mud weight | ppg | 15.3 | PPW_Lot2 |
| Largest misfit to a leak-off test accepted | ppg | 0.3 | PPW_LotTol |
| Shale log: depth, transit time and resistivity | ft, µs/ft, ohm·m | synthetic log | — |
| Casing outside diameter (surface, intermediate, production) | in. | 13.375, 9.625, 7 | SRF_OD, INT_OD, PRD_OD |
| Minimum yield strength of the grade | psi | 80,000 (L-80), 110,000 (P-110), 110,000 (P-110) | SRF_Yp, INT_Yp, PRD_Yp |
| Crossover from the upper to the lower section (TVD) | ft | 3000, 8000, 10000 | SRF_Xover, INT_Xover, PRD_Xover |
| Upper section's nominal weight | lb/ft | 68, 47, 29 | SRF_W1, INT_W1, PRD_W1 |
| Upper section's wall thickness | in. | see the Casing sheet | SRF_T1, INT_T1, PRD_T1 |
| Lower section's nominal weight | lb/ft | 72, 53.5, 32 | SRF_W2, INT_W2, PRD_W2 |
| Lower section's wall thickness | in. | see the Casing sheet | SRF_T2, INT_T2, PRD_T2 |
| Gas gradient for the gas-to-surface kick | psi/ft | 0.1 | CDS_Ggas |
| Water gradient: inside for lost returns, the backup outside | psi/ft | 0.465 | CDS_Gw |
| Overpull the top joint must allow over the hanging weight | lbf | 100000 | CDS_Overpull |
| Minimum design factor, burst | — | 1.1 | CDS_DFb |
| Minimum design factor, collapse | — | 1.125 | CDS_DFc |
| Minimum design factor, tension (pipe-body yield) | — | 1.6 | CDS_DFt |
| Minimum design factor, triaxial (von Mises) | — | 1.25 | CDS_DFvm |
Sheets
Guide— what the workbook does, where the inputs are and how the sheets connect.Pore Pressure— Eaton's pore pressure from a shale sonic or resistivity log, Gardner's overburden, Eaton's and Matthews and Kelly's fracture gradients calibrated to two leak-off tests, the mud program, and the seat and window checks, charted by depth.Casing— the surface, intermediate and production strings side by side, their shoes, muds, kicks and fracture pressures read from Pore Pressure: API TR 5C3 ratings, loads, design factors, overpull, a top-joint triaxial check and one verdict naming what each string misses.Load Lines— each string's burst and collapse loads against its ratings, charted by depth.Summary— the design basis and every check under one verdict.Test Cases— the worked example and other cases, with expected and computed results.
Four charts: the mud-weight window by depth, and each string's burst and collapse loads against its ratings.
Functions used
PO.DE.PP.EatonPO.DE.FG.EatonPO.DE.FG.MatthewsKellyPO.GM.Density.GardnerPO.GM.Stress.OverburdenPO.DE.Casing.Burst.API5C3PO.DE.TD.BuoyancyPO.GM.Stress.MinHorizontalPO.DE.Casing.VonMisesPO.DE.Casing.LoadCase
Names (216)
| Name | Refers to | Comment |
|---|---|---|
PO.DE.Casing.Axial.YieldLAMBDA |
=LAMBDA(BodyOD_in, BodyWall_in, BodyYp_psi, PI()/4*(BodyOD_in^2-(BodyOD_in-2*BodyWall_in)^2)*BodyYp_psi) |
API TR 5C3 pipe-body yield strength, Fy = (pi/4)(D^2 - d^2) Yp, [lbf]. |
PO.DE.Casing.Burst.API5C3LAMBDA |
=LAMBDA(OD_in, t_in, Yp_psi, 0.875*2*Yp_psi*t_in/OD_in) |
API TR 5C3 pipe-body internal yield (burst) pressure, Barlow with the 0.875 wall tolerance, [psi]. |
PO.DE.Casing.Collapse.API5C3LAMBDA |
=LAMBDA(OD_in, t_in, Yp_psi, Sa_psi, Output, LET(s, Sa_psi/Yp_psi, Ya, (SQRT(1-0.75*s^2)-0.5*s)*Yp_psi, kA, 2.8762+0.10679E-5*Ya+0.21301E-10*Ya^2-0.53132E-16*Ya^3, kB, 0.026233+0.50609E-6*Ya, kC, -465.93+0.030867*Ya-0.10483E-7*Ya^2+0.36989E-13*Ya^3, ba, kB/kA, xa, 3*ba/(2+ba), kF, 46950000*xa^3/(Ya*(xa-ba)*(1-xa)^2), kG, kF*ba, dtYP, (SQRT((kA-2)^2+8*(kB+kC/Ya))+(kA-2))/(2*(kB+kC/Ya)), dtPT, Ya*(kA-kF)/(kC+Ya*(kB-kG)), dtTE, (2+ba)/(3*ba), dt, OD_in/t_in, reg, IF(dt<=dtYP, 1, IF(dt<=dtPT, 2, IF(dt<=dtTE, 3, 4))), pc, IF(reg=1, 2*Ya*(dt-1)/dt^2, IF(reg=2, Ya*(kA/dt-kB)-kC, IF(reg=3, Ya*(kF/dt-kG), 46950000/(dt*(dt-1)^2)))), IF(Output=2, HSTACK(dtYP, dtPT, dtTE), IF(Output=1, HSTACK(pc, reg), pc)))) |
API TR 5C3 collapse pressure in the yield, plastic, transition or elastic regime chosen from D/t, with the axial-stress equivalent grade; Output 1 adds the regime, 2 returns the regime D/t limits, [psi]. |
PO.DE.Casing.DesignFactorLAMBDA |
=LAMBDA(Rating, Load, DF_min, LET(df, Rating/Load, HSTACK(df, IF(df>=DF_min, 1, 0)))) |
Casing design factor, rating / load, and whether it meets the named minimum design factor (1 pass, 0 fail). |
PO.DE.Casing.LoadCaseLAMBDA |
=LAMBDA(Case, D_ft, Pref_psi, Dref_ft, Gin_psift, Gout_psift, Level_ft, LET(pout, Gout_psift*D_ft, pburst, Pref_psi-Gin_psift*(Dref_ft-D_ft), pevac, IF(Case=3, 0, IF(D_ft>Level_ft, Gin_psift*(D_ft-Level_ft), 0)), IF(OR(Case<1, Case>4), NA(), IF(Case<=2, pburst-pout, pout-pevac)))) |
Casing load line at a depth: net burst (1 gas to surface, 2 lost returns with water) or net collapse (3 full evacuation, 4 partial evacuation) pressure with the external backup, [psi]. |
PO.DE.Casing.VonMisesLAMBDA |
=LAMBDA(WallOD_in, t_in, Pi_psi, Po_psi, Sa_psi, r_in, LET(ro, WallOD_in/2, ri, ro-t_in, k, ro^2-ri^2, mean, (Pi_psi*ri^2-Po_psi*ro^2)/k, dev, (Pi_psi-Po_psi)*ri^2*ro^2/(k*r_in^2), sr, mean-dev, sh, mean+dev, SQRT(((Sa_psi-sr)^2+(sr-sh)^2+(sh-Sa_psi)^2)/2))) |
Triaxial (von Mises) equivalent stress at radius r of a casing wall: Lame radial and hoop stress from internal and external pressure plus the axial stress, [psi]. |
PO.DE.FG.EatonLAMBDA |
=LAMBDA(Sv, Pp, Nu, Nu/(1-Nu)*(Sv-Pp)+Pp) |
Eaton fracture gradient from Poisson's ratio: FG = nu/(1 - nu) (Sv - Pp) + Pp, in the unit of Sv and Pp. |
PO.DE.FG.MatthewsKellyLAMBDA |
=LAMBDA(Sv, Pp, Ki, Ki*(Sv-Pp)+Pp) |
Matthews-Kelly fracture gradient from the matrix-stress coefficient: FG = Ki (Sv - Pp) + Pp, in the unit of Sv and Pp. |
PO.DE.PP.EatonLAMBDA |
=LAMBDA(Sv, Pn, Observed, Normal, Mode, LET(ratio, IF(Mode=1, Normal/Observed, Observed/Normal), expo, IF(Mode=1, 3, 1.2), IF(OR(Mode=1, Mode=2), Sv-(Sv-Pn)*ratio^expo, NA()))) |
Eaton pore pressure from the ratio of a log to its normal-compaction trend. Mode 1 sonic (exponent 3), Mode 2 resistivity (exponent 1.2). Same unit as Sv and Pn. |
PO.DE.TD.BuoyancyLAMBDA |
=LAMBDA(PipeW_lbft, PipeOD_in, PipeID_in, MWi_ppg, MWo_ppg, RhoSteel_ppg, LET(bf, 1 - (MWo_ppg*PipeOD_in^2 - MWi_ppg*PipeID_in^2) / (RhoSteel_ppg*(PipeOD_in^2 - PipeID_in^2)), HSTACK(bf, PipeW_lbft*bf))) |
Buoyancy factor of a pipe with different fluids inside and outside, and its buoyed weight per foot: {BF, lb/ft}. |
PO.GM.Density.GardnerLAMBDA |
=LAMBDA(Vp, A, B, A*Vp^B) |
Bulk density from P-wave velocity by Gardner's power law, rho = A Vp^B (g/cc; A 0.23 and B 0.25 with Vp in ft/s). |
PO.GM.Stress.OverburdenLAMBDA |
=LAMBDA(Z_ft, TVD_ft, Rho_gcc, Sv0_psi, LET(n, ROWS(TVD_ft), i, SEQUENCE(n), shift, --(i=TRANSPOSE(i)+1), d_prev, MMULT(shift, TVD_ft), r_prev, MMULT(shift, Rho_gcc), d_end, IF(TVD_ft<Z_ft, TVD_ft, Z_ft), width, IF(i>1, IF(d_end>d_prev, d_end-d_prev, 0), 0), r_end, r_prev+(Rho_gcc-r_prev)*IF(TVD_ft>d_prev, (d_end-d_prev)/(TVD_ft-d_prev), 0), d_last, INDEX(TVD_ft, n), tail, IF(Z_ft>d_last, (Z_ft-d_last)*INDEX(Rho_gcc, n), 0), sv, Sv0_psi+0.433528*(SUM(width*(r_prev+r_end)/2)+tail), IF(Z_ft<INDEX(TVD_ft, 1), NA(), HSTACK(sv, sv/Z_ft, sv/Z_ft/0.052)))) |
Overburden stress at a depth by integrating a bulk-density log (trapezoids) below the stress at its first depth: {Sv psi, psi/ft, ppg}. |
CDS_Checks |
Summary!$B$17:$B$23 |
Every check of the workbook, read from its sheet |
CDS_DFb |
Summary!$B$7 |
Minimum design factor, burst |
CDS_DFc |
Summary!$B$8 |
Minimum design factor, collapse |
CDS_DFt |
Summary!$B$9 |
Minimum design factor, tension (pipe-body yield) |
CDS_DFvm |
Summary!$B$10 |
Minimum design factor, triaxial (von Mises) |
CDS_Ggas |
Summary!$B$4 |
Gas gradient for the gas-to-surface kick, psi/ft |
CDS_Gw |
Summary!$B$5 |
Water gradient: inside for lost returns, the backup outside, psi/ft |
CDS_Inputs |
Summary!$B$4:$B$10 |
The gas and water gradients, the overpull and the four minimum design factors |
CDS_Overall |
Summary!$B$13 |
Casing design check verdict |
CDS_OverallNote |
Summary!$C$13 |
Casing design check comment |
CDS_Overpull |
Summary!$B$6 |
Overpull the top joint must allow over the hanging weight, lbf |
CDS_Steel |
Summary!$B$26 |
Density of steel, ppg |
CDS_Verdict |
Summary!$B$13 |
One verdict over every check of the workbook |
CDS_VerdictNote |
Summary!$C$13 |
One verdict over every check of the workbook comment |
INT_BF |
Casing!$C$29 |
Buoyancy factor in the mud (—) |
INT_BurstMax |
Casing!$C$34 |
Largest burst load on the string (psi), psi |
INT_CollapseMin |
Casing!$C$35 |
Least collapse rating on the string, under tension (psi), psi |
INT_Curve |
'Load Lines'!$A$25:$J$32 |
The intermediate string by depth: the burst loads for gas to surface and lost returns, the burst rating, the collapse load, the axial load and stress, the collapse rating under it, and the burst and collapse design factors |
INT_DFb1 |
Casing!$C$37 |
Burst, upper section (—) |
INT_DFb2 |
Casing!$C$38 |
Burst, lower section (—) |
INT_DFc1 |
Casing!$C$39 |
Collapse, upper section (—) |
INT_DFc2 |
Casing!$C$40 |
Collapse, lower section (—) |
INT_DFt1 |
Casing!$C$41 |
Tension, the top joint (—) |
INT_DFt2 |
Casing!$C$42 |
Tension, the lower section's top joint (—) |
INT_DFvm1 |
Casing!$C$45 |
Triaxial, the top joint (—) |
INT_FgShoe |
Casing!$C$17 |
Fracture gradient at the shoe, to 0.1 ppg (ppg), ppg |
INT_Fy1 |
Casing!$C$23 |
Pipe-body yield, upper section (lbf), lbf |
INT_Fy2 |
Casing!$C$24 |
Pipe-body yield, lower section (lbf), lbf |
INT_Htop |
Casing!$C$32 |
Buoyed hanging weight at the top (lbf), lbf |
INT_Hx |
Casing!$C$33 |
Buoyed hanging weight at the crossover (lbf), lbf |
INT_Inputs |
Casing!$C$5:$C$11 |
The intermediate string's diameter, grade, crossover and sections |
INT_MW |
Casing!$C$14 |
Mud the string is run in, outside it for collapse (ppg), ppg |
INT_OD |
Casing!$C$5 |
Casing outside diameter (in), in |
INT_Pb1 |
Casing!$C$19 |
Burst rating, upper section (psi), psi |
INT_Pb2 |
Casing!$C$20 |
Burst rating, lower section (psi), psi |
INT_Pc1 |
Casing!$C$21 |
Collapse rating with no axial load, upper section (psi), psi |
INT_Pc2 |
Casing!$C$22 |
Collapse rating with no axial load, lower section (psi), psi |
INT_Pfrac |
Casing!$C$28 |
Fracture pressure at the shoe (psi), psi |
INT_PpTD |
Casing!$C$16 |
Pore pressure there, to 0.1 ppg (ppg), ppg |
INT_Pref |
Casing!$C$26 |
Gas-kick pressure at the kick depth (psi), psi |
INT_Psurf |
Casing!$C$27 |
Surface pressure with gas to surface (psi), psi |
INT_Pull |
Casing!$C$43 |
Overpull the top joint allows at its design factor (lbf), lbf |
INT_Results |
Casing!$C$13:$C$46 |
The intermediate string's seat and loads, ratings, buoyed weights, design factors, overpull, von Mises stress and check |
INT_Shoe |
Casing!$C$13 |
Setting depth of the shoe (TVD) (ft), ft |
INT_StringCheck |
Casing!$C$46 |
String check verdict |
INT_StringCheckNote |
Casing!$H$46 |
String check comment |
INT_T1 |
Casing!$C$9 |
Upper section's wall thickness (in), in |
INT_T2 |
Casing!$C$11 |
Lower section's wall thickness (in), in |
INT_TD |
Casing!$C$15 |
Depth of the gas kick: the next TD (TVD) (ft), ft |
INT_VM |
Casing!$C$44 |
Von Mises stress, top joint's inner wall, gas to surface (psi), psi |
INT_W1 |
Casing!$C$8 |
Upper section's nominal weight (lb/ft), lb/ft |
INT_W2 |
Casing!$C$10 |
Lower section's nominal weight (lb/ft), lb/ft |
INT_Wb1 |
Casing!$C$30 |
Buoyed weight, upper section (lb/ft), lb/ft |
INT_Wb2 |
Casing!$C$31 |
Buoyed weight, lower section (lb/ft), lb/ft |
INT_Xover |
Casing!$C$7 |
Crossover from the upper to the lower section (TVD) (ft), ft |
INT_Yp |
Casing!$C$6 |
Minimum yield strength of the grade (psi), psi |
PPW_CalCheck |
'Pore Pressure'!$B$66 |
Calibration check verdict |
PPW_CalCheckNote |
'Pore Pressure'!$C$66 |
Calibration check comment |
PPW_Curve |
'Pore Pressure'!$A$72:$P$96 |
Each shale point's depth, transit time and resistivity, the two trends, the Gardner density, the overburden, the pore pressure, both fracture gradients, the mud needed, the mud program and the window |
PPW_Dt0 |
'Pore Pressure'!$B$6 |
Sonic normal trend at the surface, Δtn = Δt0·e^(−c·z), µs/ft |
PPW_DtC |
'Pore Pressure'!$B$7 |
Sonic normal trend's decay with depth, c, 1/ft |
PPW_Fg1 |
'Pore Pressure'!$B$58 |
Eaton fracture gradient at leak-off test 1, ppg |
PPW_Fg2 |
'Pore Pressure'!$B$63 |
Eaton fracture gradient at leak-off test 2, ppg |
PPW_FgShoe |
'Pore Pressure'!$B$42 |
Fracture gradient at the intermediate shoe (Eaton), ppg |
PPW_FgShoe1 |
'Pore Pressure'!$B$41 |
Fracture gradient at the surface shoe (Eaton), ppg |
PPW_FgTD |
'Pore Pressure'!$B$44 |
Fracture gradient at TD (Eaton), ppg |
PPW_GA |
'Pore Pressure'!$B$11 |
Gardner coefficient (velocity in ft/s) |
PPW_GB |
'Pore Pressure'!$B$12 |
Gardner exponent |
PPW_GccPsi |
'Pore Pressure'!$B$100 |
Pressure gradient of 1 g/cm³ of rock, psi/ft per g/cm³ |
PPW_Inputs |
'Pore Pressure'!$B$4:$B$22 |
The log the pore pressure is read from, the normal gradient, the trends, the density above the log, Gardner's constants, the fracture-gradient constants, the seats, TD and the two margins |
PPW_Ki0 |
'Pore Pressure'!$B$15 |
Matthews-Kelly Ki at zero equivalent depth |
PPW_KiSlope |
'Pore Pressure'!$B$16 |
Matthews-Kelly Ki's rise per foot of equivalent depth, 1/ft |
PPW_Kick |
'Pore Pressure'!$B$22 |
Kick margin under the fracture gradient, ppg |
PPW_Log |
'Pore Pressure'!$B$4 |
Log the pore pressure is read from |
PPW_Lot1 |
'Pore Pressure'!$B$26 |
Leak-off test 1, as an equivalent mud weight, ppg |
PPW_Lot1Z |
'Pore Pressure'!$B$25 |
Depth of leak-off test 1 (TVD), ft |
PPW_Lot2 |
'Pore Pressure'!$B$28 |
Leak-off test 2, as an equivalent mud weight, ppg |
PPW_Lot2Z |
'Pore Pressure'!$B$27 |
Depth of leak-off test 2 (TVD), ft |
PPW_LotTol |
'Pore Pressure'!$B$29 |
Largest misfit to a leak-off test accepted, ppg |
PPW_Lot_Inputs |
'Pore Pressure'!$B$25:$B$29 |
Two offset leak-off tests, their depths, and the misfit the calibration accepts |
PPW_Lot_Results |
'Pore Pressure'!$B$56:$B$66 |
The pore pressure, overburden and Eaton fracture gradient at each leak-off test, the misfit, the Poisson's ratio that matches it, and the calibration check |
PPW_MW1 |
'Pore Pressure'!$B$46 |
Mud weight, surface hole, ppg |
PPW_MW2 |
'Pore Pressure'!$B$47 |
Mud weight, intermediate hole, ppg |
PPW_MW3 |
'Pore Pressure'!$B$48 |
Mud weight, production hole, ppg |
PPW_Mic |
'Pore Pressure'!$B$101 |
Microseconds in a second, for velocity from transit time, µs/s |
PPW_Miss1 |
'Pore Pressure'!$B$59 |
Misfit, Eaton less leak-off test 1, ppg |
PPW_Miss2 |
'Pore Pressure'!$B$64 |
Misfit, Eaton less leak-off test 2, ppg |
PPW_MkShoe |
'Pore Pressure'!$B$43 |
Intermediate-shoe frac gradient (Matthews-Kelly), ppg |
PPW_Mode |
'Pore Pressure'!$B$32 |
Log mode: 1 sonic, 2 resistivity |
PPW_Nu |
'Pore Pressure'!$B$14 |
Poisson's ratio for Eaton, calibrated to leak-off tests |
PPW_NuFit1 |
'Pore Pressure'!$B$60 |
Poisson's ratio that matches leak-off test 1 |
PPW_NuFit2 |
'Pore Pressure'!$B$65 |
Poisson's ratio that matches leak-off test 2 |
PPW_Pn |
'Pore Pressure'!$B$5 |
Normal (hydrostatic) pore-pressure gradient, psi/ft |
PPW_PnEmw |
'Pore Pressure'!$B$33 |
Normal pore pressure as a mud weight, ppg |
PPW_Pp1 |
'Pore Pressure'!$B$56 |
Pore pressure at leak-off test 1, ppg |
PPW_Pp2 |
'Pore Pressure'!$B$61 |
Pore pressure at leak-off test 2, ppg |
PPW_PpShoe |
'Pore Pressure'!$B$39 |
Pore pressure at the intermediate shoe, ppg |
PPW_PpTD |
'Pore Pressure'!$B$40 |
Pore pressure at TD, ppg |
PPW_Psi |
'Pore Pressure'!$B$99 |
Pressure gradient of 1 ppg of mud, psi/ft/ppg |
PPW_R0 |
'Pore Pressure'!$B$8 |
Resistivity normal trend at the surface, Rn = R0·e^(b·z), ohm·m |
PPW_RC |
'Pore Pressure'!$B$9 |
Resistivity normal trend's growth with depth, b, 1/ft |
PPW_Results |
'Pore Pressure'!$B$32:$B$53 |
The log mode, the normal pressure, the mean density and the overburden, the pore pressure and fracture gradients at the seats and TD, each hole section's mud weight, the narrowest window and the checks |
PPW_RhoMean |
'Pore Pressure'!$B$35 |
Gardner bulk density, mean over the log, g/cm³ |
PPW_RhoTop |
'Pore Pressure'!$B$10 |
Bulk density above the first log depth, g/cm³ |
PPW_Seat1Check |
'Pore Pressure'!$B$51 |
Surface seat check verdict |
PPW_Seat1CheckNote |
'Pore Pressure'!$C$51 |
Surface seat check comment |
PPW_Seat2Check |
'Pore Pressure'!$B$52 |
Intermediate seat check verdict |
PPW_Seat2CheckNote |
'Pore Pressure'!$C$52 |
Intermediate seat check comment |
PPW_Shoe1 |
'Pore Pressure'!$B$18 |
Surface casing shoe (TVD), ft |
PPW_Shoe2 |
'Pore Pressure'!$B$19 |
Intermediate casing shoe (TVD), ft |
PPW_Sv0 |
'Pore Pressure'!$B$34 |
Overburden at the first log depth, psi |
PPW_Sv1 |
'Pore Pressure'!$B$57 |
Overburden at leak-off test 1, ppg |
PPW_Sv2 |
'Pore Pressure'!$B$62 |
Overburden at leak-off test 2, ppg |
PPW_SvTD |
'Pore Pressure'!$B$36 |
Overburden at TD, as a mud weight, ppg |
PPW_TD |
'Pore Pressure'!$B$20 |
Total depth of the production hole (TVD), ft |
PPW_Trip |
'Pore Pressure'!$B$21 |
Trip margin over the pore pressure, ppg |
PPW_Window |
'Pore Pressure'!$B$49 |
Narrowest window, fracture gradient less mud weight, ppg |
PPW_WindowCheck |
'Pore Pressure'!$B$53 |
Window check verdict |
PPW_WindowCheckNote |
'Pore Pressure'!$C$53 |
Window check comment |
PPW_WindowZ |
'Pore Pressure'!$B$50 |
Depth of the narrowest window, ft |
PRD_BF |
Casing!$D$29 |
Buoyancy factor in the mud (—) |
PRD_BurstMax |
Casing!$D$34 |
Largest burst load on the string (psi), psi |
PRD_CollapseMin |
Casing!$D$35 |
Least collapse rating on the string, under tension (psi), psi |
PRD_Curve |
'Load Lines'!$A$45:$J$52 |
The production string by depth: the burst loads for gas to surface and lost returns, the burst rating, the collapse load, the axial load and stress, the collapse rating under it, and the burst and collapse design factors |
PRD_DFb1 |
Casing!$D$37 |
Burst, upper section (—) |
PRD_DFb2 |
Casing!$D$38 |
Burst, lower section (—) |
PRD_DFc1 |
Casing!$D$39 |
Collapse, upper section (—) |
PRD_DFc2 |
Casing!$D$40 |
Collapse, lower section (—) |
PRD_DFt1 |
Casing!$D$41 |
Tension, the top joint (—) |
PRD_DFt2 |
Casing!$D$42 |
Tension, the lower section's top joint (—) |
PRD_DFvm1 |
Casing!$D$45 |
Triaxial, the top joint (—) |
PRD_FgShoe |
Casing!$D$17 |
Fracture gradient at the shoe, to 0.1 ppg (ppg), ppg |
PRD_Fy1 |
Casing!$D$23 |
Pipe-body yield, upper section (lbf), lbf |
PRD_Fy2 |
Casing!$D$24 |
Pipe-body yield, lower section (lbf), lbf |
PRD_Htop |
Casing!$D$32 |
Buoyed hanging weight at the top (lbf), lbf |
PRD_Hx |
Casing!$D$33 |
Buoyed hanging weight at the crossover (lbf), lbf |
PRD_Inputs |
Casing!$D$5:$D$11 |
The production string's diameter, grade, crossover and sections |
PRD_MW |
Casing!$D$14 |
Mud the string is run in, outside it for collapse (ppg), ppg |
PRD_OD |
Casing!$D$5 |
Casing outside diameter (in), in |
PRD_Pb1 |
Casing!$D$19 |
Burst rating, upper section (psi), psi |
PRD_Pb2 |
Casing!$D$20 |
Burst rating, lower section (psi), psi |
PRD_Pc1 |
Casing!$D$21 |
Collapse rating with no axial load, upper section (psi), psi |
PRD_Pc2 |
Casing!$D$22 |
Collapse rating with no axial load, lower section (psi), psi |
PRD_Pfrac |
Casing!$D$28 |
Fracture pressure at the shoe (psi), psi |
PRD_PpTD |
Casing!$D$16 |
Pore pressure there, to 0.1 ppg (ppg), ppg |
PRD_Pref |
Casing!$D$26 |
Gas-kick pressure at the kick depth (psi), psi |
PRD_Psurf |
Casing!$D$27 |
Surface pressure with gas to surface (psi), psi |
PRD_Pull |
Casing!$D$43 |
Overpull the top joint allows at its design factor (lbf), lbf |
PRD_Results |
Casing!$D$13:$D$46 |
The production string's seat and loads, ratings, buoyed weights, design factors, overpull, von Mises stress and check |
PRD_Shoe |
Casing!$D$13 |
Setting depth of the shoe (TVD) (ft), ft |
PRD_StringCheck |
Casing!$D$46 |
String check verdict |
PRD_StringCheckNote |
Casing!$E$46 |
String check comment |
PRD_T1 |
Casing!$D$9 |
Upper section's wall thickness (in), in |
PRD_T2 |
Casing!$D$11 |
Lower section's wall thickness (in), in |
PRD_TD |
Casing!$D$15 |
Depth of the gas kick: the next TD (TVD) (ft), ft |
PRD_VM |
Casing!$D$44 |
Von Mises stress, top joint's inner wall, gas to surface (psi), psi |
PRD_W1 |
Casing!$D$8 |
Upper section's nominal weight (lb/ft), lb/ft |
PRD_W2 |
Casing!$D$10 |
Lower section's nominal weight (lb/ft), lb/ft |
PRD_Wb1 |
Casing!$D$30 |
Buoyed weight, upper section (lb/ft), lb/ft |
PRD_Wb2 |
Casing!$D$31 |
Buoyed weight, lower section (lb/ft), lb/ft |
PRD_Xover |
Casing!$D$7 |
Crossover from the upper to the lower section (TVD) (ft), ft |
PRD_Yp |
Casing!$D$6 |
Minimum yield strength of the grade (psi), psi |
SRF_BF |
Casing!$B$29 |
Buoyancy factor in the mud (—) |
SRF_BurstMax |
Casing!$B$34 |
Largest burst load on the string (psi), psi |
SRF_CollapseMin |
Casing!$B$35 |
Least collapse rating on the string, under tension (psi), psi |
SRF_Curve |
'Load Lines'!$A$5:$J$12 |
The surface string by depth: the burst loads for gas to surface and lost returns, the burst rating, the collapse load, the axial load and stress, the collapse rating under it, and the burst and collapse design factors |
SRF_DFb1 |
Casing!$B$37 |
Burst, upper section (—) |
SRF_DFb2 |
Casing!$B$38 |
Burst, lower section (—) |
SRF_DFc1 |
Casing!$B$39 |
Collapse, upper section (—) |
SRF_DFc2 |
Casing!$B$40 |
Collapse, lower section (—) |
SRF_DFt1 |
Casing!$B$41 |
Tension, the top joint (—) |
SRF_DFt2 |
Casing!$B$42 |
Tension, the lower section's top joint (—) |
SRF_DFvm1 |
Casing!$B$45 |
Triaxial, the top joint (—) |
SRF_FgShoe |
Casing!$B$17 |
Fracture gradient at the shoe, to 0.1 ppg (ppg), ppg |
SRF_Fy1 |
Casing!$B$23 |
Pipe-body yield, upper section (lbf), lbf |
SRF_Fy2 |
Casing!$B$24 |
Pipe-body yield, lower section (lbf), lbf |
SRF_Htop |
Casing!$B$32 |
Buoyed hanging weight at the top (lbf), lbf |
SRF_Hx |
Casing!$B$33 |
Buoyed hanging weight at the crossover (lbf), lbf |
SRF_Inputs |
Casing!$B$5:$B$11 |
The surface string's diameter, grade, crossover and sections |
SRF_MW |
Casing!$B$14 |
Mud the string is run in, outside it for collapse (ppg), ppg |
SRF_OD |
Casing!$B$5 |
Casing outside diameter (in), in |
SRF_Pb1 |
Casing!$B$19 |
Burst rating, upper section (psi), psi |
SRF_Pb2 |
Casing!$B$20 |
Burst rating, lower section (psi), psi |
SRF_Pc1 |
Casing!$B$21 |
Collapse rating with no axial load, upper section (psi), psi |
SRF_Pc2 |
Casing!$B$22 |
Collapse rating with no axial load, lower section (psi), psi |
SRF_Pfrac |
Casing!$B$28 |
Fracture pressure at the shoe (psi), psi |
SRF_PpTD |
Casing!$B$16 |
Pore pressure there, to 0.1 ppg (ppg), ppg |
SRF_Pref |
Casing!$B$26 |
Gas-kick pressure at the kick depth (psi), psi |
SRF_Psurf |
Casing!$B$27 |
Surface pressure with gas to surface (psi), psi |
SRF_Pull |
Casing!$B$43 |
Overpull the top joint allows at its design factor (lbf), lbf |
SRF_Results |
Casing!$B$13:$B$46 |
The surface string's seat and loads, ratings, buoyed weights, design factors, overpull, von Mises stress and check |
SRF_Shoe |
Casing!$B$13 |
Setting depth of the shoe (TVD) (ft), ft |
SRF_StringCheck |
Casing!$B$46 |
String check verdict |
SRF_StringCheckNote |
Casing!$G$46 |
String check comment |
SRF_T1 |
Casing!$B$9 |
Upper section's wall thickness (in), in |
SRF_T2 |
Casing!$B$11 |
Lower section's wall thickness (in), in |
SRF_TD |
Casing!$B$15 |
Depth of the gas kick: the next TD (TVD) (ft), ft |
SRF_VM |
Casing!$B$44 |
Von Mises stress, top joint's inner wall, gas to surface (psi), psi |
SRF_W1 |
Casing!$B$8 |
Upper section's nominal weight (lb/ft), lb/ft |
SRF_W2 |
Casing!$B$10 |
Lower section's nominal weight (lb/ft), lb/ft |
SRF_Wb1 |
Casing!$B$30 |
Buoyed weight, upper section (lb/ft), lb/ft |
SRF_Wb2 |
Casing!$B$31 |
Buoyed weight, lower section (lb/ft), lb/ft |
SRF_Xover |
Casing!$B$7 |
Crossover from the upper to the lower section (TVD) (ft), ft |
SRF_Yp |
Casing!$B$6 |
Minimum yield strength of the grade (psi), psi |
Details
| Opens in | Needs Microsoft 365 or Excel 2024: it uses functions Excel 2016 doesn't have, such as named LAMBDAs, which show #NAME? there. |
| File | CasingDesign.xlsx, 75 KB |
| Category | Drilling |
| For agents and tools | Descriptor (.md) |
More Drilling Workbooks
AFE and Time-Depth
Microsoft 365How many days and dollars a well takes to drill by hole section, its AFE with contingency, the actuals against plan and its NPV at that cost.
Cementing Program
Microsoft 365How much cement and displacement each casing string takes, whether the placed column breaks the formation down and how long the job runs.
Completion Schematic
Microsoft 365Where each casing string, completion component and perforation sits in MD and TVD, and whether the well's two barriers hold, on a live schematic.
Drilling Program
Microsoft 365What mud weight, flow rate and trip speed each hole section of a vertical well can take, from pore and fracture pressure off a sonic log.
Fracture Treatment Design
PO Add-in + Microsoft 365How long a fracture a proppant mass buys and how to pump it, from unified fracture design through geometry and pump schedule to proppant and uplift.
Well Control Pack
Microsoft 365How to kill a kick and how big a kick the shoe takes: kill sheet, kick tolerance, MAASP, bullheading limits and BOP accumulator sizing.
Well Integrity Review
Microsoft 365Whether one well's casing, annuli, completion and abandonment barriers hold, from casing ratings and annulus pressure limits to tubing loads and plug cost.
Well Planning
Microsoft 365Where a directional well goes and whether the drill string can trip and rotate it, from a minimum-curvature survey to soft-string torque and drag.
Need a workbook we don't have? Suggest a Workbook









