Description
How heavy must the mud be in each hole section, and will the casing seats hold it? You enter a shale log with its normal-compaction trends, the casing seats and margins, two offset leak-off tests and the mud on hand. You read off the pore pressure by Eaton's method, the overburden, the fracture gradient by Eaton and by Matthews and Kelly, each section's mud weight, whether each seat holds the next section's mud, the narrowest window, and the barite and blend that make the production mud.
Parameters:
- Logs and trends: the log mode
PP_Mode(1 sonic, 2 resistivity), the normal pore-pressure gradientPP_Pn(psi/ft), the sonic trend Δtn = Δt0·e^(−c·z) (PP_Dt0µs/ft,PP_DtC1/ft), the resistivity trend Rn = R0·e^(b·z) (PP_R0ohm·m,PP_RC1/ft), the bulk density above the first log depthPP_RhoTop(g/cm³), and Gardner's coefficientPP_GAand exponentPP_GB - Fracture gradient: Eaton's Poisson's ratio
PP_Nu, and Matthews and Kelly's Ki as a line in the equivalent depth,PP_Ki0+PP_KiSlope·Di - Casing seats and margins: the surface and intermediate shoes
PP_Shoe1,PP_Shoe2and TDPP_TD(ft TVD), the trip marginPP_Tripand the kick marginPP_Kick(ppg) - Leak-off tests: two depths and results,
PP_Lot1Z/PP_Lot1andPP_Lot2Z/PP_Lot2(ft, ppg), and the misfit acceptedPP_LotTol(ppg) - Mud on hand: the active system
PP_Active(bbl), the barite densityPP_Barite(ppg), the premix weightPP_Premix(ppg), the batch to blendPP_Batch(bbl) and the pit capacityPP_Pits(bbl) - Log table: depth, shale transit time and shale resistivity at each point (ft, µs/ft, ohm·m)
How to use it: The logs are synthetic: on their trends to 8,000 ft, then slower and more conductive than them through a transition zone. Paste the shale points' depth, transit time and resistivity from your logs into the table, keeping the depths increasing, and drop sand and carbonate points. Pick each normal trend over a normally pressured interval, and calibrate ν, and the Ki line, to the area's leak-off and formation-integrity tests. The log mode picks whether pore pressure comes from the sonic or the resistivity; a mode other than 1 or 2 fails. The density for the overburden is taken from the sonic by Gardner's law in a column, since the example logs have no density log: with a density log, type the density into the Gardner column in place of its formula. Read the checks: the surface and intermediate seats fail when the next section's mud with the kick margin is over the fracture gradient at the shoe; the window warns where it narrows below the kick margin; the calibration warns when Eaton's line misses a leak-off test by more than the accepted misfit; a blend outside the two muds fails, and a weighted-up system larger than the pits warns. The mud-weight window chart draws pore pressure, the mud program, both fracture gradients and the overburden against depth, and a second chart draws the sonic against its trend.
Method: The normal trends are Δtn = Δt0·e^(−c·z) and Rn = R0·e^(b·z). Gardner's density is ρb = A·Vp^B with Vp = 10⁶/Δt ft/s. The overburden at each depth is Sv = Sv0 + 0.433528 ∫ρb dz, a trapezoid between log points, with Sv0 = 0.433528·ρtop·z at the first log depth; its mud weight is Sv/(0.052·z). Eaton's pore pressure, in ppg, is Pp = Sv − (Sv − Pn)(Δtn/Δto)³ from the sonic, or (Ro/Rn)^1.2 from the resistivity. Eaton's fracture gradient is FG = ν/(1 − ν)·(Sv − Pp) + Pp. Matthews and Kelly's is FG = Ki·(Sv − Pp) + Pp, with Ki read at the equivalent depth Di = z·(Sv − Pp)/(Sv − Pn), the depth at which normally pressured rock carries the same matrix stress. Eaton's line is calibrated against two offset leak-off tests. A value at a casing seat or a leak-off test is interpolated linearly between the log points either side of it. Each hole section's mud weight is the largest Pp + trip margin over the section, rounded up to 0.1 ppg, and the window at each depth is Eaton's fracture gradient less the section's mud weight. A leak-off test of result LOT matches Eaton's line at ν = (LOT − Pp)/(Sv + LOT − 2 Pp). A last block weights the intermediate mud up to the production weight with barite and blends a batch from it and a premix. Barite to weight V bbl from W1 to W2 is V (W2 − W1)/(ρa − W2) bbl, or 42 ρa per bbl in lbm, and a blend of Vf bbl at Wf from muds A and B takes Va = Vf (Wf − Wb)/(Wa − Wb).
Example: The drilling family's reference well, the one the casing-design and cement-volume sheets use: a vertical onshore well with 13⅜-in. surface casing at 4,000 ft, a 12¼-in. intermediate hole to 10,000 ft cased with 9⅝-in., and an 8½-in. production hole to 13,000 ft. Its shale log runs every 500 ft from 1,000 to 13,000 ft. The sonic trend is 170 e^(−0.00006 z) µs/ft and the resistivity trend 0.6 e^(0.00008 z) ohm·m. Above the log the rock is taken at 1.95 g/cm³, and the normal gradient is 0.465 psi/ft. Eaton's ν is 0.40, and Ki is 0.40 + 0.00003 per foot of equivalent depth. The margins are 0.3 ppg for trips and 0.5 ppg for a kick. The offset leak-off tests read 14.5 ppg at 4,000 ft and 15.3 ppg at 10,000 ft. On hand are 800 bbl of active mud, API barite at 35 ppg, a 16.0 ppg premix, a 400 bbl batch to blend, and 1,000 bbl of pits.
The normal pressure is 0.465/0.052 = 8.94 ppg. The overburden starts at 0.433528 × 1.95 × 1,000 = 845 psi and reaches 18.31 ppg at TD. At 13,000 ft the trend reads 77.9 µs/ft against a measured 98.0, so (77.9/98.0)³ = 0.503 and Pp = 18.31 − 9.37 × 0.503 = 13.60 ppg; Eaton's fracture gradient there is 13.60 + (0.4/0.6)(18.31 − 13.60) = 16.74 ppg. At the intermediate shoe Pp is 10.19 ppg, Eaton's fracture gradient 15.42 ppg and Matthews and Kelly's 15.36 ppg. At the surface shoe Eaton gives 14.41 ppg. The hole sections take 9.3, 10.5 and 13.9 ppg mud. The 13.9 ppg production mud with the 0.5 ppg kick margin, 14.4 ppg, is under the 15.42 ppg at the intermediate shoe, and the 10.5 ppg intermediate mud, 11.0 ppg with the margin, is under the 14.41 ppg at the surface shoe, so both seats hold. The narrowest window is 1.79 ppg, at 10,500 ft, just below the intermediate shoe. Eaton's line misses the 14.5 ppg leak-off test by −0.09 ppg and the 15.3 ppg one by +0.12 ppg, within the 0.3 ppg accepted, and the tests alone would set ν to 0.404 and 0.395. Weighting the 800 bbl from 10.5 to 13.9 ppg takes 189,498 lbm of barite (1,895 sacks) and adds 128.9 bbl, so the system grows to 929 bbl, inside the 1,000 bbl of pits. A 400 bbl batch of 13.9 ppg blends from 152.7 bbl of the active mud and 247.3 bbl of the 16.0 ppg premix.
Functions used
None: the blueprint calculates with Excel's own functions.
Names (86)
| Name | Refers to | Comment |
|---|---|---|
PO.DE.PP.EatonLAMBDA |
=LAMBDA(Sv, Pn, Observed, Normal, Mode, LET(ratio, IF(Mode=1, Normal/Observed, Observed/Normal), expo, IF(Mode=1, 3, 1.2), IF(OR(Mode=1, Mode=2), Sv-(Sv-Pn)*ratio^expo, NA()))) |
Eaton pore pressure from the ratio of a log to its normal-compaction trend. Mode 1 sonic (exponent 3), Mode 2 resistivity (exponent 1.2). Same unit as Sv and Pn. |
PO.DE.FG.EatonLAMBDA |
=LAMBDA(Sv, Pp, Nu, Nu/(1-Nu)*(Sv-Pp)+Pp) |
Eaton fracture gradient from Poisson's ratio: FG = nu/(1 - nu) (Sv - Pp) + Pp, in the unit of Sv and Pp. |
PO.DE.FG.MatthewsKellyLAMBDA |
=LAMBDA(Sv, Pp, Ki, Ki*(Sv-Pp)+Pp) |
Matthews-Kelly fracture gradient from the matrix-stress coefficient: FG = Ki (Sv - Pp) + Pp, in the unit of Sv and Pp. |
PO.DE.Mud.WeightUpLAMBDA |
=LAMBDA(V_bbl, MW_start_ppg, MW_target_ppg, Rho_agent_ppg, LET(added, V_bbl*(MW_target_ppg-MW_start_ppg)/(Rho_agent_ppg-MW_target_ppg), mass, 42*Rho_agent_ppg*added, HSTACK(mass, mass/100, added, V_bbl+added))) |
Barite (or another weighting agent) to raise a mud system to a target weight, and the volume it adds: {lb, 100-lb sacks, bbl added, final bbl}. |
PO.DE.Mud.BlendLAMBDA |
=LAMBDA(V_final_bbl, MW_a_ppg, MW_b_ppg, MW_target_ppg, LET(vol_a, V_final_bbl*(MW_target_ppg-MW_b_ppg)/(MW_a_ppg-MW_b_ppg), HSTACK(vol_a, V_final_bbl-vol_a))) |
Volumes of a heavy and a light mud that blend to a target weight and final volume: {bbl of mud A, bbl of mud B}. |
PO.GM.Density.GardnerLAMBDA |
=LAMBDA(Vp, A, B, A*Vp^B) |
Bulk density from P-wave velocity by Gardner's power law, rho = A Vp^B (g/cc; A 0.23 and B 0.25 with Vp in ft/s). |
PO.GM.Stress.OverburdenLAMBDA |
=LAMBDA(Z_ft, TVD_ft, Rho_gcc, Sv0_psi, LET(n, ROWS(TVD_ft), i, SEQUENCE(n), shift, --(i=TRANSPOSE(i)+1), d_prev, MMULT(shift, TVD_ft), r_prev, MMULT(shift, Rho_gcc), d_end, IF(TVD_ft<Z_ft, TVD_ft, Z_ft), width, IF(i>1, IF(d_end>d_prev, d_end-d_prev, 0), 0), r_end, r_prev+(Rho_gcc-r_prev)*IF(TVD_ft>d_prev, (d_end-d_prev)/(TVD_ft-d_prev), 0), d_last, INDEX(TVD_ft, n), tail, IF(Z_ft>d_last, (Z_ft-d_last)*INDEX(Rho_gcc, n), 0), sv, Sv0_psi+0.433528*(SUM(width*(r_prev+r_end)/2)+tail), IF(Z_ft<INDEX(TVD_ft, 1), NA(), HSTACK(sv, sv/Z_ft, sv/Z_ft/0.052)))) |
Overburden stress at a depth by integrating a bulk-density log (trapezoids) below the stress at its first depth: {Sv psi, psi/ft, ppg}. |
PP_Mode |
$B$4 |
Log the pore pressure is read from: 1 sonic, 2 resistivity |
PP_Pn |
$B$5 |
Normal (hydrostatic) pore-pressure gradient, psi/ft |
PP_Dt0 |
$B$6 |
Sonic normal trend at the surface, Δtn = Δt0·e^(−c·z), µs/ft |
PP_DtC |
$B$7 |
Sonic normal trend's decay with depth, c, 1/ft |
PP_R0 |
$B$8 |
Resistivity normal trend at the surface, Rn = R0·e^(b·z), ohm·m |
PP_RC |
$B$9 |
Resistivity normal trend's growth with depth, b, 1/ft |
PP_RhoTop |
$B$10 |
Bulk density above the first log depth, g/cm³ |
PP_GA |
$B$11 |
Gardner coefficient (velocity in ft/s) |
PP_GB |
$B$12 |
Gardner exponent |
PP_Nu |
$B$14 |
Poisson's ratio for Eaton, calibrated to leak-off tests |
PP_Ki0 |
$B$15 |
Matthews-Kelly Ki at zero equivalent depth |
PP_KiSlope |
$B$16 |
Matthews-Kelly Ki's rise per foot of equivalent depth, 1/ft |
PP_Shoe1 |
$B$18 |
Surface casing shoe (TVD), ft |
PP_Shoe2 |
$B$19 |
Intermediate casing shoe (TVD), ft |
PP_TD |
$B$20 |
Total depth of the production hole (TVD), ft |
PP_Trip |
$B$21 |
Trip margin over the pore pressure, ppg |
PP_Kick |
$B$22 |
Kick margin under the fracture gradient, ppg |
PP_Inputs |
$B$4:$B$22 |
The log the pore pressure is read from, the normal gradient, the two logs' normal-compaction trends, the density above the log, Gardner's constants, the fracture-gradient constants, the casing seats, TD and the two margins |
PP_Lot1Z |
$B$25 |
Depth of leak-off test 1 (TVD), ft |
PP_Lot1 |
$B$26 |
Leak-off test 1, as an equivalent mud weight, ppg |
PP_Lot2Z |
$B$27 |
Depth of leak-off test 2 (TVD), ft |
PP_Lot2 |
$B$28 |
Leak-off test 2, as an equivalent mud weight, ppg |
PP_LotTol |
$B$29 |
Largest misfit to a leak-off test accepted, ppg |
PP_Lot_Inputs |
$B$25:$B$29 |
Two offset leak-off tests, their depths, and the misfit the calibration accepts |
PP_Active |
$B$32 |
Active system at the intermediate mud weight, bbl |
PP_Barite |
$B$33 |
Weighting agent density (API barite), ppg |
PP_Premix |
$B$34 |
Weight of the premixed heavy mud in storage, ppg |
PP_Batch |
$B$35 |
Batch of production mud to blend, bbl |
PP_Pits |
$B$36 |
Surface pit capacity, bbl |
PP_Mud_Inputs |
$B$32:$B$36 |
The active system, the barite, the premix, the blend batch and the pit capacity |
PP_PnEmw |
$B$39 |
Normal pore pressure as a mud weight, ppg |
PP_Sv0 |
$B$40 |
Overburden at the first log depth, psi |
PP_SvTD |
$B$41 |
Overburden at TD, as a mud weight, ppg |
PP_LogCheck |
$B$42 |
Log check verdict |
PP_LogCheckNote |
$C$42 |
Log check comment |
PP_PpShoe |
$B$44 |
Pore pressure at the intermediate shoe, ppg |
PP_PpTD |
$B$45 |
Pore pressure at TD, ppg |
PP_FgShoe1 |
$B$46 |
Fracture gradient at the surface shoe (Eaton), ppg |
PP_FgShoe |
$B$47 |
Fracture gradient at the intermediate shoe (Eaton), ppg |
PP_MkShoe |
$B$48 |
Intermediate-shoe frac gradient (Matthews-Kelly), ppg |
PP_FgTD |
$B$49 |
Fracture gradient at TD (Eaton), ppg |
PP_MW1 |
$B$51 |
Mud weight, surface hole, ppg |
PP_MW2 |
$B$52 |
Mud weight, intermediate hole, ppg |
PP_MW3 |
$B$53 |
Mud weight, production hole, ppg |
PP_Window |
$B$54 |
Narrowest window, fracture gradient less mud weight, ppg |
PP_WindowZ |
$B$55 |
Depth of the narrowest window, ft |
PP_Seat1Check |
$B$56 |
Surface seat check verdict |
PP_Seat1CheckNote |
$C$56 |
Surface seat check comment |
PP_Seat2Check |
$B$57 |
Intermediate seat check verdict |
PP_Seat2CheckNote |
$C$57 |
Intermediate seat check comment |
PP_WindowCheck |
$B$58 |
Window check verdict |
PP_WindowCheckNote |
$C$58 |
Window check comment |
PP_Results |
$B$39:$B$58 |
The normal pressure, the overburden, the pore pressure and fracture gradients at the casing seats and TD, each hole section's mud weight, the narrowest window and the three checks |
PP_Pp1 |
$B$61 |
Pore pressure at leak-off test 1, ppg |
PP_Sv1 |
$B$62 |
Overburden at leak-off test 1, ppg |
PP_Fg1 |
$B$63 |
Eaton fracture gradient at leak-off test 1, ppg |
PP_Miss1 |
$B$64 |
Misfit, Eaton less leak-off test 1, ppg |
PP_NuFit1 |
$B$65 |
Poisson's ratio that matches leak-off test 1 |
PP_Pp2 |
$B$66 |
Pore pressure at leak-off test 2, ppg |
PP_Sv2 |
$B$67 |
Overburden at leak-off test 2, ppg |
PP_Fg2 |
$B$68 |
Eaton fracture gradient at leak-off test 2, ppg |
PP_Miss2 |
$B$69 |
Misfit, Eaton less leak-off test 2, ppg |
PP_NuFit2 |
$B$70 |
Poisson's ratio that matches leak-off test 2 |
PP_CalCheck |
$B$71 |
Calibration check verdict |
PP_CalCheckNote |
$C$71 |
Calibration check comment |
PP_Lot_Results |
$B$61:$B$71 |
The pore pressure, overburden and Eaton fracture gradient at each leak-off test, the misfit, the Poisson's ratio that matches it, and the calibration check |
PP_WeightUp |
$A$75:$D$75 |
Barite to weight the active system from the intermediate to the production mud weight: lbm, sacks, volume added, system after |
PP_BlendA |
$B$77 |
Blend: active mud in the batch, bbl |
PP_BlendB |
$B$78 |
Blend: premix in the batch, bbl |
PP_After |
$B$79 |
Active system after weighting up, bbl |
PP_BlendCheck |
$B$80 |
Blend check verdict |
PP_BlendCheckNote |
$C$80 |
Blend check comment |
PP_PitCheck |
$B$81 |
Pit check verdict |
PP_PitCheckNote |
$C$81 |
Pit check comment |
PP_Mud_Results |
$B$77:$B$81 |
The blend's two volumes, the system after weighting up, and the blend and pit checks |
PP_Curve |
$A$87:$P$111 |
Each shale point's depth, transit time and resistivity, the two normal trends, the Gardner density, the overburden, the pore pressure, both fracture gradients, the mud needed, the mud program and the window |
PP_Psi |
$B$114 |
Pressure gradient of 1 ppg of mud, psi/ft/ppg |
PP_GccPsi |
$B$115 |
Pressure gradient of 1 g/cm³ of rock, psi/ft per g/cm³ |
PP_Mic |
$B$116 |
Microseconds in a second, for velocity from transit time, µs/s |
Details
| Inserts | 116 rows × 16 columns |
| Category | Drilling Engineering |
| For agents and tools | Descriptor (.md) |
Related Blueprints
Surge and Swab Trip Speed
Calculates surge and swab pressures section by section and finds the fastest trip speed that neither breaks the shoe nor swabs in a kick.
Primary Cement Job Design
How much cement and displacement a two-slurry primary cement job takes, and whether the placed column breaks the formation down.
BOP Accumulator Sizing
Sizes a BOP accumulator unit from bottle size, precharge and the stack's functions, and gives the bottles needed and the pressure left.
Casing Design
Whether a two-section casing string holds its burst, collapse, tension and triaxial loads by API TR 5C3, with the design factors down the string.
Hole Cleaning and Solids Control
Whether the planned ROP and flow clean the hole, from cuttings concentration and slip velocity, and how much solids the mud carries.
Well Control Kill Sheet
Produces a kill sheet by Wait and Weight or Driller's method with kill mud weight, ICP, FCP, strokes, MAASP and the drill pipe schedule.
Need a custom calculation? Request a Blueprint


